삼각형 출력 예제를 통한 여러 가지 소스 비교 with Io

콘솔에 삼각형

         *
       * *
      *   *
     *     *
    *       *
   *         *
  *           *
 *             *
*****************

을 출력하는 Io 소스 코드를 작성해 보자. 이런 소스 코드의 작성은 학원이나 학교에서 프로그래밍 입문자에게 과제로 많이 주어지는 것 중의 하나이다. 코끼리를 보거나 만진 사람들이 저마다 그 생김새를 말할 때 제각기 다르게 표현할 수 있듯이 이런 소스 코드의 작성도 알고 보면 얼마든지 많은 방법이 있을 것이다. 여기서는 쉬운 코드 부터 작성해 보고 차츰차츰 소스를 바꾸어 가면서 Io 프로그래밍의 기초부분을 터득해 보기로 한다.

모든 소스 코드에서는 삼각형 출력 부분 담당 함수 printTriange()를 별도로 구현하였다.

우선 첫번 째 예제는 Io의 컨솔 출력 메소드 println의 사용법만 알면 누구나 코딩할 수 있는 매우 단순한 소스 코드이다.


삼각형 출력 예제 1
/*
 *  Filename: printTriangle1.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle1.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
     "        *        " println
     "       * *       " println
     "      *   *      " println
     "     *     *     " println
     "    *       *    " println
     "   *         *   " println
     "  *           *  " println
     " *             * " println
     "*****************" println
)

printTriange()




위의 소스 코드는 아무 알고리즘도 없는 너무 단순한 코드이다. 이런 코드를 작성했다간 출력 모양이나 크기를 변경해야 하는 상황을 맞이하면 위드프로세서로 문서 만드는 것 이상으로 많은 수작업을 하거나 아니면 포기하는 지경에 이를 수도 있다. 그래서 다음 처럼 좀 더 나은 소스 코드를 작성하였다.



삼각형 출력 예제 2
/*
 *  Filename: printTriangle2.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle2.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    for (i, 0, 7,
        for (k, 0, 7-i,
            " " print
        )
        for (k, 0, 2*i,
            if (k == 0 or k == 2*i) then (
                 "*" print
            ) else (
                 " " print
            )
        )
        for (k, 0, 7-i,
            " " print
        )
        "" println
    )

    for (i, 0, 16,
        "*" print
    )
    "" println
)

printTriange()



위의 소스 코드는 Io의 컨솔 출력 메소드 println과 print 그리고 for 반복 구문을 적절히 사용하여 구현되었다. 숫자 몇 곳만 수정하면 출력되는 삼각형의 크기를 바꿀 수 있다. 한 줄에 출력될 문자를 구성하는 알고리즘은 위의 예제와 근본적으로 같지만 print를 사용하지 않고, 그대신 Sequence를 만들어 한 즐씩 출력하는 소스 코드를 다음 예제와 같이 작성해 보았다.



삼각형 출력 예제 3
/*
 *  Filename: printTriangle3.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle3.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    line := Sequence clone
    line2 := Sequence clone
    for (i, 0, 17,
        line append(" " at(0))
    )

    for (i, 0, 7,
        line2 := line
        line2 = line2  asMutable atPut(8-i, "*" at(0))
        line2 = line2  asMutable atPut(8+i, "*" at(0))
        line2 println
    )

    line2 = line
    for (i, 0, 16,
        line2 = line2 asMutable atPut(i, "*"at(0))
    )
    line2 println
)

printTriange()



별(*) 문자를 이용하여 삼각형을 출력하는 일은 빈칸 문자와 별 문자를 적당한 좌표(위치)에 촐력하는 일이다. 다음은 빈칸 문자 17개로 이루어진 string을 참조하는 변수 whites와 별(*) 문자 17개로 이루어진 string을 참조하는 변수 stars를 초기화하는 Io 코드이다.

    whites := " " repeated(17)
    stars := "*" repeated(17)

(이는 Python, Ruby , Groovy 언어의 표현식 whites = " " * 17 에 대응하는 Io 코드이다.)

whites가 참조하는 스트링에 한 두 개의 빈칸 문자를 별(*) 문자로 바꾸어 출력하는 기법

        line2 = whites
        line2 = line2 asMutable atPut(8-i, stars at(8-i))
        line2 = line2 asMutable atPut(8+i, stars at(8+i))

을 써서 대부분의 줄을 출력하고, 마지막줄은 stars가 참조하는 스트링을 출력하는 소스 코드이다.




삼각형 출력 예제 4
/*
 *  Filename: printTriangle4.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle4.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    whites := " " repeated(17)
    stars := "*" repeated(17)
    line2 := whites
    line2 = line2 asMutable atPut(8, stars at(8))
    line2 println
    for (i, 1, 7,
        line2 = whites
        line2 = line2 asMutable atPut(8-i, stars at(8-i))
        line2 = line2 asMutable atPut(8+i, stars at(8+i))
        line2 println
    )
    stars println
)

printTriange()



빈칸 문자를 별(*) 문자로 바꾸는 for 반복문 안만 다르게 작성해 보았다.



삼각형 출력 예제 5
/*
 *  Filename: printTriangle5.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle5.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    whites := " " repeated(17)
    stars := "*" repeated(17)
    line2 := whites
    line2 = line2 asMutable atPut(8, stars at(8))
    line2 println
    for (i, 1, 7,
        line2 = whites slice(0, 8-i) .. "*" .. whites slice(8-i+1, 8+i) .. "*" .. whites slice(8+i+1, whites size)
        line2 println
    )
    stars println
)

printTriange()




출력되는 삼각형이 좌우 대칭이라는 사실에 착안하여, 다음 소스 코드에서는  각 줄을 처음 8자, 중앙 한 문자, 끝 8자(처음 8자의 역순)로 string을 만들어 출력하였다.



삼각형 출력 예제 6
/*
 *  Filename: printTriangle6.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle6.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    whites := " " repeated(8)
    stars  := "*" repeated(8)
    start := 8
    line := whites .. "*" .. whites
    line println

    for (i, 7, 1, -1,
        line = whites slice(0, i) .. stars slice(i, i+1) .. whites slice(i+1)
        line = line .. " " .. line asMutable reverse
        line println
    )

    line = stars .. "*" .. stars
    line println
)

printTriange()




다음 소스 코드는 한 줄에 출력될 문자열의 데이터를 17비트 이진법 수로 구성하고, 이 이진법수의 비트가 0인 곳에는 빈칸을, 1인 곳에는 별(*)을 출력하는 기법으로 작성되었다.



삼각형 출력 예제 7
/*
 *  Filename: printTriangle7.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle7.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    start := 0x100
    total := 0
    val := start
    data := ""

    for (k, 0, 7,
        val = (start shiftLeft(k)) | (start shiftRight(k))
        data = val asString toBase(2)
        for (i, 0, 16 - data size,
            " " print
        )
        for (i, 0, data size - 1,
            if (data slice(i, i+1) == "0") then (
                " " print
            ) else (
                "*" print
            )
        )
        " " println
        total = total + val
    )

    val = (start shiftLeft(8)) | (start shiftRight(8))
    total = total + val
    data = total asString toBase(2)
    for (i, 0, 16 - data size,
        " " print
    )
    for (i, 0,  data size - 1,
        if ( data slice(i, i+1) == "0") then (
            " " print
        ) else (
            "*" print
        )
    )
        " " println
)

printTriange()




기본적인 원리는 위의 소스 코드와 같지만 이진법수의 한 비트 마다 한 문자씩 츨력하는 대신에 출력된 한 줄의 string을 완성하여 이를 println() 으로 출력하는 기법으로 재작성한 것이 다음의 소스 코드이다. replaceSeq() 메소드를 이용하여 모든 0을 빈칸으로, 모든 1을 별(*) 문자로 바꾸었으며, 별(*) 문자만으로 이루어진 마지막 줄 출력을 위해 변수 total을 준비하였다. for 반복 구문의 블럭 내에서 구문

            total = total | val

이 하는 일이 무엇인지 이해할 수 있으면 좋겠다.




삼각형 출력 예제 8
/*
 *  Filename: printTriangle8.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle8.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    zeros  := "00000000"
    start := 0x100
    total := 0
    val := start
    line := ""
    data := ""

    for (k, 0, 7,
        val = (start shiftLeft(k)) | (start shiftRight(k))
        data = val asString toBase(2)
        line = zeros slice(0, 17 - data size) .. data
        line = line asMutable replaceSeq("0", " ")
        line = line asMutable replaceSeq("1", "*")
        line println
        total = total | val
    )

    val = (start shiftLeft(8)) | (start shiftRight(8))
    total = total | val
    line = total asString toBase(2)
    line = line asMutable replaceSeq("0", " ")
    line = line asMutable replaceSeq("1", "*")
    line println
)

printTriange()




소스 코드가 처음 것 보다 매우 복잡해졌지만, Io의 리스트를 이용해서 구현해 보았다.  별(*) 문자만으로 이루어진 마지막 줄 출력을 위해 리스트 타입의 변수 last를 준비하였다. 또 리스트에 속한 모든 item을 출력하는 구문

        data join("") println

은 짧지만 꽤 쓸 만한 구문이다. 이는 Groovy 언어 코드의

        println( data.join() )

에 해당하는 Io 언어 코드이다.



삼각형 출력 예제 9
/*
 *  Filename: printTriangle9.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle9.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    start := 8
    data := List clone
    last := List clone
    17 repeat(data append(" "))
    17 repeat(last append(" "))

    data atPut(start, "*")
    last atPut(start, "*")
    data join("") println
    data atPut(start, " ")

    for (k, 1, 7,
        data atPut(start - k, "*")
        last atPut(start - k, "*")
        data atPut(start + k, "*")
        last atPut(start + k, "*")
        data join("") println
        data atPut(start - k, " ")
        data atPut(start + k, " ")
    )

    last atPut(start - 8, "*")
    last atPut(start + 8, "*")
    last join("") println
)

printTriange()





다음 예제는 수학에서 xy-좌표평면에 점을 찍듯이 논리 구문

             (x + y - 8 == 0) or (y - x + 8 == 0) or (y - 8 == 0)

가 참이 되는 위치에 별(*) 문자를 표시하는 기법으로 작성된 소스 코드이다.




삼각형 출력 예제 10
/*
 *  Filename: printTriangle10.io
 *            Print a triangle on console.
 *
 *  Execute: io printTriangle10.io
 *
 *      Date:  2008/05/07
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

printTriange := method(
    a := nil
    for (y, 0, 8,
        for (x, 0,16,
            if ((x + y - 8 == 0) or (y - x + 8 == 0) or (y - 8 == 0)) then (
                a = "*"
            ) else (
                a = " "
            )
            a print
        )
        "" println
    )
)

printTriange()








이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.