삼각형 출력 예제를 통한 여러 가지 소스 비교 with Groovy

콘솔에 삼각형

         *
       * *
      *   *
     *     *
    *       *
   *         *
  *           *
 *             *
*****************

을 출력하는 Groovy 소스 코드를 작성해 보자. 이런 소스 코드의 작성은 학원이나 학교에서 프로그래밍 입문자에게 과제로 많이 주어지는 것 중의 하나이다. 코끼리를 보거나 만진 사람들이 저마다 그 생김새를 말할 때 제각기 다르게 표현할 수 있듯이 이런 소스 코드의 작성도 알고 보면 얼마든지 많은 방법이 있을 것이다. 여기서는 쉬운 코드 부터 작성해 보고 차츰차츰 소스를 바꾸어 가면서 Groovy 프로그래밍의 기초부분을 터득해 보기로 한다.

모든 소스 코드에서는 삼각형 출력 부분 담당 함수 printTriange()를 별도로 구현하였다.

우선 첫번 째 예제는 Groovy의 컨솔 출력 함수 println()의 사용법 만 알면 누구나 코딩할 수 있는 매우 단순한 소스 코드이다.


삼각형 출력 예제 1
/*
 *  Filename: printTriangle1.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle1.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
     println("        *        ")
     println("       * *       ")
     println("      *   *      ")
     println("     *     *     ")
     println("    *       *    ")
     println("   *         *   ")
     println("  *           *  ")
     println(" *             * ")
     println("*****************")
}

printTriange()




위의 소스 코드는 아무 알고리즘도 없는 너무 단순한 코드이다. 이런 코드를 작성했다간 출력 모양이나 크기를 변경해야 하는 상황을 맞이하면 워드프로세서로 문서 만드는 것 이상으로 많은 수작업을 하거나 아니면 포기하는 지경에 이를 수도 있다. 그래서 다음 처럼 좀 더 나은 소스 코드를 작성하였다.



삼각형 출력 예제 2
/*
 *  Filename: printTriangle2.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle2.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    for (i in 0..<8) {
        for (k in 0..<8-i) {
            print(" ")
        }
        for (k in 0..<2*i+1) {
            if (k == 0 || k == 2*i)
                print("*")
            else
                print(" ")
        }
        for (k in 0..<8-i) {
            print(" ")
        }
        println()
    }

    for (i in 0..<17) {
        print("*")
    }
    println()
}

printTriange()



위의 소스 코드는 Groovy의 컨솔 출력 함수 println()와 print() 그리고 for 반복 구문을 적절히 사용하여 구현되었다. 숫자 몇 곳만 수정하면 출력되는 삼각형의 크기를 바꿀 수 있다. 한 줄에 출력될 문자를 구성하는 알고리즘은 위의 예제와 근본적으로 같지만 print()를 사용하지 않고, 그대신 char[] 타입의 배열을 만들어 한 즐씩 출력하는 소스 코드를 다음 예제와 같이 작성해 보았다.
또 빈칸 17개의 문자로 구성된 스트링을 생성하기 위한 구문

    def whites = " "*17

도 음미해볼 만하다. (string*number 또는 list*number의 구문은 Python, Ruby 언어에서도 지원된다.)



삼각형 출력 예제 3
/*
 *  Filename: printTriangle3.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle3.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def line = " "*17
    def line2 = " "*17 as char[]

    for (int i in 0..<8) {
        ine2 = " "*17 as char[]
        line2[8-i] =  '*'
        line2[8+i] =  '*'
        println(new String(line2))
    }

    line2 = " "*17 as char[]
    for (i in 0..<17) {
        line2[i] =  '*'
    }
    println(new String(line2))
}

printTriange()



별(*) 문자를 이용하여 삼각형을 출력하는 일은 빈칸 문자와 별 문자를 적당한 좌표(위치)에 촐력하는 일이다. StringBuffer를 사용하더라도 한 줄의 출력을 빈칸 만으로로 구성된 string(소스 코드에서 변수 whites가 참조하는 string 값)을 기본으로 하고, 이 string에 한 두 개의 빈칸을 바꾸어 출력하는 기법으로 작성한 것이 다음 소스 코드이다. 단, 마지막 줄에 츨력될 string은 stars라는 별도의 변수로 처리하였다.


삼각형 출력 예제 4
/*
 *  Filename: printTriangle4.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle4.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def whites = " "*17
    def stars  = "*"*17
    def line2 = new StringBuffer(whites)
    line2 = line2.replace(8, 9, "*")
    println(line2)
    for (int i in 1..<8) {
        line2 = new StringBuffer(whites)
        line2 = line2.replace(8-i, 8+i, stars.substring(8-i, 8+i))
        line2 = line2.replace(8-i+1, 8+i-1, whites.substring(8-i, 8+i-1))
        println(line2)
    }
    println(stars)
}

printTriange()




빈칸 문자를 별(*) 문자로 바꾸기 위해, 위의 소스 코드에서는 StringBuffer.replace() 메소드를 이용하였지만, 다음 소스 코드에서는 StringBuffer.setCharAt() 메소드를 이용하였다.



삼각형 출력 예제 5
/*
 *  Filename: printTriangle5.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle5.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def whites = " "*17
    def stars  = "*"*17
    def line = new StringBuffer(whites)
    def start = 8
    line = line.replace(start, start, "*")
    println(line)
    for (int i in 1..<8) {
        line = new StringBuffer(whites)
        line.setCharAt(start - i, stars.charAt(start - i))
        line.setCharAt(start + i, stars.charAt(start + i))
        println(line)
    }
    println(stars)
}

printTriange()




출력되는 삼각형이 좌우 대칭이라는 사실에 착안하여, 다음 소스 코드에서는  각 줄을 처음 8자, 중앙 한 문자, 끝 8자(처음 8자의 역순)로 string을 만들어 출력하였다.



삼각형 출력 예제 6
/*
 *  Filename: printTriangle6.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle6.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def whites = " "*8
    def stars  = "*"*8
    def start = 8
    def line = new StringBuffer(whites)
    line.append('*')
    line.append(whites)
    println(line)

    for (int i in 1..<8) {
        line = new StringBuffer(whites)
        line.setCharAt(start - i, stars.charAt(start - i))
        print(line)
        print(" ")
        line.reverse()
        println(line)
    }

    line = new StringBuffer(stars)
    line.append('*')
    line.append(stars)
    println(line)
}

printTriange()




다음 소스 코드는 한 줄에 출력될 문자열의 데이터를 17비트 이진법 수로 구성하고, 이 이진법수의 비트가 0인 곳에는 빈칸을, 1인 곳에는 별(*)을 출력하는 기법으로 작성되었다.



삼각형 출력 예제 7
/*
 *  Filename: printTriangle7.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle7.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def start = 0x100
    def total = 0
    def val = start
    def data = ""

    for (k in 0..<8) {
        val = (start << k) | (start >> k)
        data = Integer.toString(val, 2)
        for (i in 0..<17 - data.length()) {
            print(' ')
        }
        for (i in 0..<data.length()) {
            if (data[i] == '0')
                print(' ')
            else
                print('*')
        }
        println()
        total += val
    }

    val = (start << 8) | (start >> 8)
    total += val
    data = Integer.toString(total, 2)
    for (i in 0..<17 - data.length()) {
        print(' ')
    }
    for (i in 0..<data.length()) {
        if (data[i] == '0')
            print(' ')
        else
            print('*')
    }
    println()
}

printTriange()




기본적인 원리는 위의 소스 코드와 같지만 이진법수의 한 비트 마다 한 문자씩 츨력하는 대신에 출력된 한 줄의 string을 완성하여 이를 println() 으로 출력하는 기법으로 재작성한 것이 다음의 소스 코드이다. String.replaceAll() 메소드를 이용하여 모든 0을 빈칸으로, 모든 1을 별(*) 문자로 바꾸었으며, 별(*) 문자만으로 이루어진 마지막 줄 출력을 위해 변수 total을 준비하였다. for 반복 구문의 블럭 내에서 구문

            total |= val

이 하는 일이 무엇인지 이해할 수 있으면 좋겠다.




삼각형 출력 예제 8
/*
 *  Filename: printTriangle8.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle8.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def zeros  = "00000000"
    def start = 0x100
    def total = 0
    def val = start
    def line = ""
    def data = ""

    for (k in 0..<8) {
        val = (start << k) | (start >> k)
        data = Integer.toString(val, 2)
        line = zeros[0..<17-data.length()] + data
        line = line.replaceAll("0", " ")
        line = line.replaceAll("1", "*")
        println(line)
        total |= val
    }

    val = (start << 8) | (start >> 8)
    total |= val
    line = Integer.toString(total, 2)
    line = line.replaceAll("0", " ")
    line = line.replaceAll("1", "*")
    println(line)
}

printTriange()




소스 코드가 처음 것 보다 매우 복잡해졌지만, Groovy의 리스트를 이용해서 구현해 보았다. Groovy 언어 외에 Python, Ruby 언어 같은 스크립팅 언어에서도 리스트와 맵은 매우 중요하게 취급되며, 구문에서도 이를 위한 문법을 제공하고 있다. 별(*) 문자만으로 이루어진 마지막 줄 출력을 위해 리스트 타입의 변수 last를 준비하였다. 또 리스트에 속한 모든 item을 출력하는 부분

        data.each { print it }
        println

은 Groovy 언어에서 많이 사용되는 클로저(closure)를 이용한 구문이다. 이 두 줄은 리스트의 join 메소드를 이용하여

        println( data.join() )

로 해도 같은 출력을 얻는다.




삼각형 출력 예제 9
/*
 *  Filename: printTriangle9.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle9.groovy
 *
 *      Date:  2008/04/01
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def start = 8
    def data = [" "]*17
    def last = [" "]*17

    data[start] = "*"
    last[start] = "*"
    data.each { print it }
    println()
    data[start] = " "

    for (k in 1..<8) {
        data[start - k] = "*"
        last[start - k] = "*"
        data[start + k] = "*"
        last[start + k] = "*"
        println( data.join() )
        data[start - k] = " "
        data[start + k] = " "
    }

    last[start - 8] = "*"
    last[start + 8] = "*"
    println(  last.join() )
}

printTriange()





다음 예제는 수학에서 xy-좌표평면에 점을 찍듯이 논리 구문

             (x + y - 8 == 0) || (y - x + 8 == 0) || (y - 8 == 0)

가 참이 되는 위치에 별(*) 문자를 표시하는 기법으로 작성된 소스 코드이다.




삼각형 출력 예제 10
/*
 *  Filename: printTriangle10.groovy
 *            Print a triangle on console.
 *
 *  Execute: groovy printTriangle10.groovy
 *
 *      Date:  2008/04/03
 *    Author:  PH Kim   [ pkim (AT) scripts.pe.kr ]
 */

def printTriange() {
    def a
    for (y in 0..8) {
        for (x in 0..16) {
            if ((x + y - 8 == 0) || (y - x + 8 == 0) || (y - 8 == 0))
                a = '*'
            else
                a = ' '
            print a
        }
        println()
    }
}

printTriange()








이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.